etiquette de prix sur graph

**Oliv44** · 06/08/2010 05h13

Bonjour,

J'ai un soucis de programation: J'ai un indic qui me met une jolie petite flèche sur le graph lors d'un croisement du D et du K d'un Stochastique. Rien que de l'ordinaire. J'ai souhaité y ajouter une étiquette de prix sur la bougie, au prix exact auquel a lieu le croisement. Et là, de suite cela se corse pour mon niveau. En fait cela fonctionne et même bien car l'etiquette apparait au prix du croisement (disons sur un croisement long, etiquette verte). Puis le chandelier vis sa vie et l'etiquette reste. Mais au chandelier suivant, une nouvelle etiquette (verte toujour) apparait alors qu'il n'y a pas eu de nouveau croisement et ainsi de suite jusqu'au moment ou un croisement inverse (sto passe short, etiquette rouge). Regarder le screenshot sera certainement plus parlant.

je souhaiterais que les etiquettes n'apparaissent qu'aprés un croisement, pas sur tous les chandeliers.

Pourtant les conditions de D (qui se nomme bleu[i]) et de K (jaune[i]) fonctionnent bien pour les flèches. Que dois-je changer dans le code?
Merci.

for( i=limit; i >= 0; i--)
{

bleu[i] = iStochastic(NULL, 0, 13, 5, 3, 3, 0, MODE_SIGNAL, i);
jaune[i] = iStochastic(NULL, 0, 13, 5, 3, 3, 0, MODE_MAIN, i);

if (jaune[i+1] > bleu[i+1] && jaune[i] < bleu[i])
{
bufferDo[i]=High[i]+(iATR(NULL,0,20,i)/2);
ObjectCreate("SELL SIGNAL: " + DoubleToStr(Time[0],0),OBJ_ARROW,0,Time[0],Close[0]);
ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[0],0),OBJPROP_ARROWCODE,5);
ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[0],0),OBJPROP_COLOR,SignalPriceSELL);
}
else bufferDo[i]= EMPTY_VALUE;

if (jaune[i+1] < bleu[i+1] && jaune[i] > bleu[i])
{
bufferUp[i]= Low[i]-(iATR(NULL,0,20,i)/2);
ObjectCreate("BUY SIGNAL: " + DoubleToStr(Time[0],0),OBJ_ARROW,0,Time[0],Close[0]);
ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[0],0),OBJPROP_ARROWCODE,5);
ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[0],0),OBJPROP_COLOR,SignalPriceBUY);
}
else bufferUp[i]= EMPTY_VALUE;

**pipsforever** · 06/08/2010 10h36

voilà, à priori ca fonctionne

Il fallait juste remplacer les [0] par des [i].

Code HTML:

//+------------------------------------------------------------------+
//|                                Stochastique Signal étiquette.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//|                             Dragon Colette Signal filtré 2&3.mq4 |
//|                      Copyright © 2010, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_width1 0
#property indicator_width2 0
#property indicator_color1 ForestGreen
#property indicator_color2 Red
//---- input parameters


extern   color    SignalPriceBUY = Lime;
extern   color    SignalPriceSELL = Red;
//extern bool etiquettes = true;


//---- buffers
double bufferUp[];
double bufferDo[];
double bufferTr[];
double bleu[];
double jaune[];


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
   IndicatorBuffers(4);
   SetIndexBuffer(0,bufferUp);
   SetIndexStyle(0,DRAW_ARROW); 
   SetIndexArrow(0,225); //241
   SetIndexLabel(0,"UpArrow");
   SetIndexBuffer(1,bufferDo);
   SetIndexStyle(1,DRAW_ARROW); 
   SetIndexArrow(1,226); //242
   SetIndexLabel(1,"DownArrow");
   SetIndexBuffer(2,jaune);
   SetIndexBuffer(3,bleu);


   return(0);
}
int deinit()
{
   return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
   int i,limit;
   int counted_bars=IndicatorCounted();

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
           limit=Bars-counted_bars;
   
   for( i=limit; i >= 0; i--) 
   {
   
          bleu[i]  = iStochastic(NULL, 0, 13, 5, 3, 3, 0, MODE_SIGNAL, i);
          jaune[i]   = iStochastic(NULL, 0, 13, 5, 3, 3, 0, MODE_MAIN, i);
          
         
         if (jaune[i+1] > bleu[i+1] && jaune[i] < bleu[i])
           {
          bufferDo[i]=High[i]+(iATR(NULL,0,20,i)/2);                               
          ObjectCreate("SELL SIGNAL: " + DoubleToStr(Time[i],0), OBJ_ARROW, 0, Time[i], Close[i]);
          ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_ARROWCODE, SYMBOL_RIGHTPRICE);
          ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_COLOR, SignalPriceSELL);
           }
            else     bufferDo[i]= EMPTY_VALUE;
            
            
            
        if (jaune[i+1] < bleu[i+1] && jaune[i] > bleu[i])     
          {
         bufferUp[i]= Low[i]-(iATR(NULL,0,20,i)/2);
         
         ObjectCreate("BUY SIGNAL: " + DoubleToStr(Time[i],0), OBJ_ARROW, 0, Time[i], Close[i]);
         ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_ARROWCODE, SYMBOL_RIGHTPRICE);
         ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_COLOR, SignalPriceBUY);
          }
            else     bufferUp[i]= EMPTY_VALUE;
   
    }
   return(0);
}

**Oliv44** · 06/08/2010 15h58

Bon, on ne se connait pas, mais je te dis tout net: DES BISOUS PARTOUT!

Merci, j'ai ramé une bonne partie de la nuit a courir après les codes qui comportent ces tiquettes et une bonne prise de tête. C'est beau un forum ou l'on post un pbs à 5h30, et une bonne âme vous aide à 10h30.

merci merci merci pipsForever.

**pipsforever** · 06/08/2010 18h54

lol, mais de rien.
Petite modif ici, j'ai ajouté "ObjectsDeleteAll(0,OBJ_ARROW)" dans la "deinit" pour que quand tu enlève l'indicateur, les étiquettes s'effacent.

Code HTML:

//+------------------------------------------------------------------+
//|                                Stochastique Signal étiquette.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//|                             Dragon Colette Signal filtré 2&3.mq4 |
//|                      Copyright © 2010, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_width1 0
#property indicator_width2 0
#property indicator_color1 ForestGreen
#property indicator_color2 Red
//---- input parameters


extern   color    SignalPriceBUY = Lime;
extern   color    SignalPriceSELL = Red;
//extern bool etiquettes = true;


//---- buffers
double bufferUp[];
double bufferDo[];
double bufferTr[];
double bleu[];
double jaune[];


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
   IndicatorBuffers(4);
   SetIndexBuffer(0,bufferUp);
   SetIndexStyle(0,DRAW_ARROW); 
   SetIndexArrow(0,225); //241
   SetIndexLabel(0,"UpArrow");
   SetIndexBuffer(1,bufferDo);
   SetIndexStyle(1,DRAW_ARROW); 
   SetIndexArrow(1,226); //242
   SetIndexLabel(1,"DownArrow");
   SetIndexBuffer(2,jaune);
   SetIndexBuffer(3,bleu);


   return(0);
}
int deinit()
{
 ObjectsDeleteAll(0,OBJ_ARROW);

   return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
   int i,limit;
   int counted_bars=IndicatorCounted();

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
           limit=Bars-counted_bars;
   
   for( i=limit; i >= 0; i--) 
   {
   
          bleu[i]  = iStochastic(NULL, 0, 13, 5, 3, 3, 0, MODE_SIGNAL, i);
          jaune[i]   = iStochastic(NULL, 0, 13, 5, 3, 3, 0, MODE_MAIN, i);
          
         
         if (jaune[i+1] > bleu[i+1] && jaune[i] < bleu[i])
           {
          bufferDo[i]=High[i]+(iATR(NULL,0,20,i)/2); 
                              
          /*ObjectCreate("SELL SIGNAL: " + DoubleToStr(Time[i],0),OBJ_ARROW,0,Time[i],Close[i]);
          ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i],0),OBJPROP_ARROWCODE,5);
          ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i],0),OBJPROP_COLOR,SignalPriceSELL);  */   
          ObjectCreate("SELL SIGNAL: " + DoubleToStr(Time[i],0), OBJ_ARROW, 0, Time[i], Close[i]);
          ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_ARROWCODE, SYMBOL_RIGHTPRICE);
          ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_COLOR, SignalPriceSELL);
           }
            else     bufferDo[i]= EMPTY_VALUE;
            
            
            
        if (jaune[i+1] < bleu[i+1] && jaune[i] > bleu[i])     
          {
         bufferUp[i]= Low[i]-(iATR(NULL,0,20,i)/2);
         /*ObjectCreate("BUY SIGNAL: " + DoubleToStr(Time[i],0),OBJ_ARROW,0,Time[i],Close[i]);
         ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i],0),OBJPROP_ARROWCODE,5);
         ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i],0),OBJPROP_COLOR,SignalPriceBUY);*/
         ObjectCreate("BUY SIGNAL: " + DoubleToStr(Time[i],0), OBJ_ARROW, 0, Time[i], Close[i]);
         
         ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_ARROWCODE, SYMBOL_RIGHTPRICE);
         ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i],0), OBJPROP_COLOR, SignalPriceBUY);
          }
            else     bufferUp[i]= EMPTY_VALUE;
   
    }
   return(0);
}

**Oliv44** · 07/08/2010 02h15

Nom de nom, tu lis dans mes pensées.

J'ai laissé tourner cet aprem et visualisé le résultat ce soir après le biberon du ptit dernier...

Et qu'est-ce que je me suis dit? ben, que cela serait bien que je n'ai pas à ré-initialiser le template pour que tout disparaisse...

Et paf, t'est là. Nickel.

Je profite de tes lumières en matière de tiquettes pour te demander si tu saurais pas comment faire pour que le calcul (donc la production d'étiquette) ne commence que quand on lance l'indic. En effet, si il indique le prix au moment exact du croisement quand MT4 (et l'indic) sont en marche, toutes les étiquettes précédant l'allumage de la plateforme n'indiquent que le Close là ou il y a eu croisement. Sans interêt donc.

J'ai bien essayé de passer par
SetIndexDrawBegin(0,Bars-CountBars);
SetIndexDrawBegin(1,Bars-CountBars);
avec extern int CountBars =100; dans l'entête mais cela ne marche que pour les flèches .

Par contre j'ai remarqué que les étiquette produites aprés calcul (prix exact du croisement) restent une fois l'indic relancé. Il stocke l'info qqpart?

C'est bien pratique ces étiquettes. Car une flèche de signal située sur la bougie est bien trompeuse (piège mental). On se dit que l'on serait entré là, disons pas loin du + haut pour un short, ou du plus bas pour un long. L'étiquette est implacable: c'est tel prix. Précis.

Dans tous les cas, MERCI.

**pipsforever** · 07/08/2010 02h41

dans le début de la boucle : for( i=limit; i >= 0; i--)
remplace le "limit" par ton CountedBar de ton extern, ainsi l'indicateur n'affichera que sur X bougies

heu pour l'étiquette l'étiquette qui reste, je pense que ce doit être réglable avec un "truc" du genre ObjectMove, mais j'en suis pas sur, jamais utilisé.

Un petit plus sur ton indic serait un alerte

**huralp** · 07/08/2010 08h04

Plutôt sympa, mais serait encore plus fonctionnel avec un Stochastique paramétrable et collerait plus à la réalité du marché si utilisait le SMI plutôt que le stochastique. Indicateur quasi similaire mais moins sensible aux Bruits.

**Oliv44** · 07/08/2010 20h52

Bonjour

Alors, pour le paramétrable, c'etait un peu un brouillon. D'ailleurs il y avait des trucs qui trainaient dans le code et qui n'avaient rien à y faire ...

La version définitive avec un bonus: la version SMI pour Huralp (et les autres)

Merci à pips forever sans qui rien n'aurait abouti.

**pipsforever** · 07/08/2010 21h18

Je suis de bonne humeur aujourd'hui

J'ai remis les étiquettes sur le close ici, elles n'apparaissent qu'à a clôture de la bougie, comme ça pas de problème de figement.
Il y a aussi des alertes, utilisable ou non via "use_alert"

Code:

//+------------------------------------------------------------------+
//|                                Stochastique Signal étiquette.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_width1 0
#property indicator_width2 0
#property indicator_color1 ForestGreen
#property indicator_color2 Red
//---- input parameters

extern int K =13;
extern int D =3;
extern int Ralentissement =5;
extern int Matype =3;
extern bool use_alert=true;  
extern string        Attention ="seul les etiquettes apparues après";
extern string        ° ="la mise en service de l indicateur sont ";
extern string        °° ="juste.Les précédentes reflètent le";
extern string        °°° ="cours d ouverture";
extern int CountBarsTikettes =10;
extern   color    SignalPriceBUY = Lime;
extern   color    SignalPriceSELL = Red;



//---- buffers
double bufferUp[];
double bufferDo[];
double bufferTr[];
double bleu[];
double jaune[];


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
   IndicatorBuffers(4);
   SetIndexBuffer(0,bufferUp);
   SetIndexStyle(0,DRAW_ARROW); 
   SetIndexArrow(0,225); //241
   SetIndexLabel(0,"UpArrow");
   SetIndexBuffer(1,bufferDo);
   SetIndexStyle(1,DRAW_ARROW); 
   SetIndexArrow(1,226); //242
   SetIndexLabel(1,"DownArrow");
   SetIndexBuffer(2,jaune);
   SetIndexBuffer(3,bleu);


   return(0);
}
int deinit()

{
   ObjectsDeleteAll(0,OBJ_ARROW);
   return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
   int i,limit;
   int counted_bars=IndicatorCounted();

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
           limit=Bars-counted_bars;
   
   for( i=CountBarsTikettes; i >= 0; i--) 
   {
   
          bleu[i]  = iStochastic(NULL, 0, K, D, Ralentissement, Matype, 0, MODE_SIGNAL, i);
          jaune[i]   = iStochastic(NULL, 0, K, D, Ralentissement, Matype, 0, MODE_MAIN, i);
      
         
         if (jaune[i+1] > bleu[i+1] && jaune[i] < bleu[i])
           {
           bufferDo[i]=High[i]+(iATR(NULL,0,20,i)/2);                          
          
           }
            else     bufferDo[i]= EMPTY_VALUE;
            
            
            
            if(bufferDo[i+1]==High[i+1]+(iATR(NULL,0,20,i+1)/2))
            {
             if(use_alert && Volume[i]==1)
             {
              Alert("(", Symbol(), ")  - Sto Down!!!");
             }
             ObjectCreate("SELL SIGNAL: " + DoubleToStr(Time[i+1],0),OBJ_ARROW,0,Time[i+1],Close[i+1]);
             ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i+1],0),OBJPROP_ARROWCODE,SYMBOL_RIGHTPRICE);
             ObjectSet("SELL SIGNAL: " + DoubleToStr(Time[i+1],0),OBJPROP_COLOR,SignalPriceSELL);   
            }
           
        if (jaune[i+1] < bleu[i+1] && jaune[i] > bleu[i])     
          {
         bufferUp[i]= Low[i]-(iATR(NULL,0,20,i)/2);
         
          }
            else     bufferUp[i]= EMPTY_VALUE;
            
            if(bufferUp[i+1]==Low[i+1]-(iATR(NULL,0,20,i+1)/2))
            {
              if(use_alert && Volume[i]==1)
              {
              Alert("(", Symbol(), ")  - Sto Up!!!");
              }
             ObjectCreate("BUY SIGNAL: " + DoubleToStr(Time[i+1],0),OBJ_ARROW,0,Time[i+1],Close[i+1]);
             ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i+1],0),OBJPROP_ARROWCODE,5);
             ObjectSet("BUY SIGNAL: " + DoubleToStr(Time[i+1],0),OBJPROP_COLOR,SignalPriceBUY);
            }
   
    }
    
    
	    
   return(0);
}

**Oliv44** · 08/08/2010 03h02

Mais ou s'arrêtera t-on?

On en fait un EA? non je déconne.

Enfin cela en jette, son, lumière ...

Mais perso, je m'arrête là, car en fait, les pbs de figement c'est justement pour cela que j'ai cherché à mettre une Tiquette (c'est l'influance du ptit dernier qui apprend à parler, quoi que "étiquette", il n'en est pas encore là).

En fait, j'ai juste besoin de connaitre en temps réel la valeur de prix lors du croisement d'un ... indic custom qui ressemble au Sto, mais également si il y a croisement sur une envolée de prix mais qui s'invalide en fait au cours de la même bougie. Là, une tiquette (arheu) apparaît alors qu'il n'y a pas eu croisement en fin de cpte. Je teste pour voir si cela peut servir comme condition déclencheur de trade dans un robot. Ca croise, ça ouvre au prix X.
Donc toutes les conditions i+1, ce n'est pas pour moi. Mais merci tout de même. En tous cas, en 2 jours j'en aurais appris un peu + en MQL4 grâce à toi.

Vivement ce soir que cela tourne un peu.

Merci.Oliv.

etiquette de prix sur graph

LinkBack

Outils de la discussion

Affichage

etiquette de prix sur graph

Magic PipsForever !

Magic, de + en + fort !

No problèmes

Wahoo !!

Discussions similaires

trade sur graph

'decouper' le graph en 'periodes'

graph en tick sur MT4 ?

meta4 et graph

graph on graph

Visitez Trader Forex en un clic

Ressources Forex

Analyses/Actualité

Trading

Forum Forex

Calendrier

Marchés en live

Brokers Forex

NewsLetter